Съдържание

# SFDialogs.DialogControl service

The DialogControl service manages the controls belonging to a dialog defined with the Basic Dialog Editor. Each instance of the current service represents a single control within a dialog box.

The focus is set on getting and setting the values displayed by the controls of the dialog box. Formatting is accessible via the XControlModel and XControlView properties.

Note that the unique DialogControl.Value property content varies according to the control type.

A special attention is given to controls of type tree control. It is easy to populate a tree, either branch by branch, or with a set of branches at once. Populating a tree control can be performed statically or dynamically.

The SFDialogs.DialogControl service is closely related to the SFDialogs.Dialog service.

## Извикване на услугата

Преди да използвате услугата DialogControl, библиотеката ScriptForge трябва да бъде заредена или импортирана:

• Макросите на Basic изискват зареждане на библиотеката ScriptForge чрез следния оператор:
GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
• Скриптовете на Python изискват импортиране от модула scriptforge:
from scriptforge import CreateScriptService

The DialogControl service is invoked from an existing Dialog service instance through its Controls() method. The dialog must be initiated with the SFDialogs.Dialog service.

          Dim myDialog As Object, myControl As Object
          Set myDialog = CreateScriptService("SFDialogs.Dialog", "GlobalScope", myLibrary, DialogName)
          Set myControl = myDialog.Controls("myTextBox")
          myControl.Value = "Dialog started at " & Now()
          myDialog.Execute()
          ' ... process the controls actual values
          myDialog.Terminate()

         from time import localtime, strftime
         dlg = CreateScriptService('SFDialogs.Dialog', 'GlobalScope', lib_name, dlg_name)
         text = dlg.Controls('myTextBox')
         text.Value = "Dialog started at " + strftime("%a, %d %b %Y %H:%M:%S", localtime())
         dlg.Execute()
         # ... process the controls actual values
         dlg.Terminate()

## Retrieving the DialogControl instance that triggered a control event

An instance of the DialogControl service can be retrieved via the SFDialogs.DialogEvent service, provided that the dialog was initiated with the Dialog service. In the example below, oControl contains the DialogControl instance that triggered the control event.

          Sub aControlEventHandler(ByRef poEvent As Object)
              Dim oControl As Object
              Set oControl = CreateScriptService("SFDialogs.DialogEvent", poEvent)
              ' ...
          End Sub

Или чрез Python:

         def control_event_handler(event: uno):
             oControl = CreateScriptService('SFDialogs.DialogEvent', event)
             # ...

Обърнете внимание, че в предишните примери префиксът "SFDialogs." може да бъде пропуснат, когато това се смята за подходящо.

## Обработка на изключения в обработчиците на събития

When creating an event handler for control events it is good practice to handle errors inside the subroutine itself. For instance, suppose the event handler below is called when button is clicked.

        Sub OnButtonClicked(ByRef oEvent As Object)
        On Local Error GoTo Catch
            Dim oControl As Object
            oControl = CreateScriptService("DialogEvent", oEvent)
            ' Обработваме събитието
            Exit Sub
        Catch:
            MsgBox SF_Exception.Description
            SF_Exception.Clear
        End Sub

Извикайте SF_Exception.Clear, ако не искате грешката да се разпространява, след като приключи изпълнението на диалога.

В Python за обработка на изключенията използвайте нормални блокове try/except, както е показано по-долу:

        def on_button_clicked(event=None):
            try:
                oControl = CreateScriptService("DialogEvent", event)
                # Обработваме събитието
            except Exception as e:
                # The object "bas" below is an instance of the Basic service
                bas.MsgBox(str(e))

## Control types

The DialogControl service is available for these control types:

• Button • CheckBox • ComboBox • CurrencyField • DateField • FileControl | • FixedLine • FixedText • FormattedField • GroupBox • Hyperlink • ImageControl | • ListBox • NumericField • PatternField • ProgressBar • RadioButton • ScrollBar | • TableControl • TextField • TimeField • TreeControl

## Свойства

Име | Само за четене | Тип | Applicable to | Описание
--- | --- | --- | --- | ---
Border | Да | String | Button, … | The Border property refers to the surrounding of the control: "3D", "FLAT" or "NONE".
Cancel | Не | Boolean | Button | Specifies if a command button has or not the behaviour of a Cancel button.
Caption | Не | String | Button, CheckBox, FixedLine, FixedText, GroupBox, Hyperlink, RadioButton | Specifies the text associated with the control.
ControlType | Да | String | Всички | One of the types listed above.
CurrentNode | Не | UNO обект | TreeControl | The currently upmost node selected in the tree control. Refer to XmutableTreeNode in Application Programming Interface (API) documentation for detailed information.
Default | Не | Boolean | Button | Specifies whether a command button is the default (OK) button.
Enabled | Не | Boolean | Всички | Specifies if the control is accessible with the cursor.
Format | Не | String | DateField, TimeField, FormattedField (само за четене) | Specifies the format used to display dates and times. It must be one these strings: For dates: "Standard (short)", "Standard (short YY)", "Standard (short YYYY)", "Standard (long)", "DD/MM/YY", "MM/DD/YY", "YY/MM/DD", "DD/MM/YYYY", "MM/DD/YYYY" , "YYYY/MM/DD", "YY-MM-DD", "YYYY-MM-DD". For times: "24h short", "24h long", "12h short", "12h long".
ListCount | Да | Long | ComboBox, ListBox, TableControl | Specifies the number of rows in a ListBox, a ComboBox or a TableControl.
ListIndex | Не | Long | ComboBox, ListBox, TableControl | Specifies which item is selected in a ListBox, a ComboBox or a TableControl.
Locked | Не | Boolean | ComboBox, CurrencyField, DateField, FileControl, FormattedField, ListBox, NumericField, PatternField, TextField, TimeField | Specifies if the control is read-only.
MultiSelect | Не | Boolean | ListBox | Specifies whether a user can make multiple selections in a listbox.
Name | Да | String | Всички | The name of the control.
Page | Не | Integer | Всички | Диалогът може да има няколко страници, които потребителят да обхожда стъпка по стъпка. Свойството Page на обекта от тип Dialog определя коя страница на диалога е активна. The Page property of a control defines the page of the dialog on which the control is visible.
Parent | Да | Dialog service | Всички | The parent SFDialogs.Dialog class object instance.
Picture | Не | String | Button, ImageControl | Specifies the file name containing a bitmap or other type of graphic to be displayed on the specified control. The filename must comply with the FileNaming attribute of the ScriptForge.FileSystem service.
RootNode | Да | UNO обект | TreeControl | An object representing the lowest root node (usually there is only one such root node). Refer to XmutableTreeNode in Application Programming Interface (API) documentation for detailed information.
RowSource | Не | Array of strings | ComboBox, ListBox | Specifies the data contained in a combobox or a listbox.
TabIndex | Да | Numeric | All | The TabIndex property specifies a control's place in the tab order in the dialog.
Text | Да | String | ComboBox, FileControl, FormattedField, PatternField, TextField | Gives access to the text being displayed by the control.
TipText | Не | String | Всички | Specifies the text that appears as a tooltip when you hold the mouse pointer over the control.
TripleState | Не | Boolean | CheckBox | Specifies if the checkbox control may appear dimmed (grayed) or not.
URL | Не | String | Hyperlink | The URL to open when the control is clicked.
Value | Не | Variant |  | Refer to Value property
Visible | Не | Boolean | Всички | Specifies if the control is hidden or visible.
XControlModel | Да | UNO обект | Всички | The UNO object representing the control model. Refer to XControlModel and UnoControlDialogModel in Application Programming Interface (API) documentation for detailed information.
XControlView | Да | UNO обект | Всички | The UNO object representing the control view. Refer to XControl and UnoControlDialog in Application Programming Interface (API) documentation for detailed information.
XTreeDataModel | Да | UNO обект | TreeControl | The UNO object representing the tree control data model. Refer to XMutableTreeDataModel in Application Programming Interface (API) documentation for detailed information.

## The Value property

Control type | Тип | Описание
--- | --- | ---
Button | Boolean | For toggle buttons only
CheckBox | Boolean or Integer | 0, False: not checked 1, True: checked 2: grayed, don't know
ComboBox | String | The selected value. The ListIndex property is an alternate option.
CurrencyField | Числа |
DateField | Date |
FileControl | String | A file name formatted in accordance with the FileNaming property of the ScriptForge.FileSystem service
FormattedField | String or Numeric |
ListBox | Низ или масив от низове | The selected row(s) as a scalar or as an array depending on the MultiSelect attribute
NumericField | Числа |
PatternField | String |
ProgressBar | Числа | Must be within the predefined bounds
RadioButton | Boolean | Each button has its own name. They are linked together if their TAB positions are contiguous. If a radiobutton is set to True, the other related buttons are automatically set to False
ScrollBar | Числа | Must be within the predefined bounds
TableControl | Array | One-dimensional array with the data of the currently selected row.
TextField | String | The text appearing in the field
TimeField | Date |

There is no Value property for GroupBox, Hyperlink, ImageControl and TreeControl dialog controls.

## Свойства за събития

Свойствата On… връщат низ във формат URI с референция към скрипта, задействан от събитието. Свойствата On… могат да се задават по програмен път.
Прочетете спецификацията в Scripting Framework URI Specification (на английски).

Име | Само за четене | Description as labeled in the Basic IDE
--- | --- | ---
OnActionPerformed | Да | Изпълнение на действие
OnAdjustmentValueChanged | Да | При нагласяване
OnFocusGained | Да | При получаване на фокуса
OnFocusLost | Да | При загубване на фокуса
OnItemStateChanged | Да | Променено състояние на обект
OnKeyPressed | Да | Натиснат клавиш
OnKeyReleased | Да | Отпуснат клавиш
OnMouseDragged | Да | Преместена мишка с натиснат клавиш
OnMouseEntered | Да | Мишката е вътре
OnMouseExited | Да | Мишката е отвън
OnMouseMoved | Да | Преместена мишка
OnMousePressed | Да | Натиснат бутон на мишката
OnMouseReleased | Да | Отпуснат бутон на мишката
OnNodeExpanded | Не | (Not in Basic IDE) when the expansion button is pressed on a node in a tree control
OnNodeSelected | Не | (Not in Basic IDE) when a node in a tree control is selected
OnTextChanged | Да | Променен текст

Присвояването на събития чрез развойната среда на Basic и присвояването на събития чрез макроси взаимно се изключват.

## Методи

List of Methods in the DialogControl Service
AddSubNode AddSubTree CreateRoot | FindNode Resize SetFocus | SetTableData WriteLine

## AddSubNode

Create and return a new node of the tree control as a UNO object subordinate to a parent node. Refer to XMutableTreeNode in Application Programming Interface (API) documentation for detailed information.

This method may be called before displaying the dialog box to build the initial tree. It may also be called from a dialog or control event - using the OnNodeExpanded event - to complete the tree dynamically.

### Синтаксис:

svc.AddSubNode(parentnode: uno, displayvalue: str, opt datavalue: any): uno

### Параметри:

parentnode: A node UNO object, of type com.sun.star.awt.tree.XMutableTreeNode.

displayvalue: The text appearing in the tree control box.

datavalue: Any value associated with the new node. datavalue may be a string, a number or a date. Omit the argument when not applicable.

### Пример:

LibreOffice Basic and Python examples pick up current document's myDialog dialog from Standard library.

##### В Basic

          Dim oDlg As Object, myTree As Object, myNode As Object, theRoot As Object
          Set oDlg = CreateScriptService("Dialog",,, "myDialog")
          Set myTree = oDlg.Controls("myTreeControl")
          Set theRoot = myTree.CreateRoot("Tree top")
          Set myNode = myTree.AddSubNode(theRoot, "A branch ...")

##### В Python

         dlg = CreateScriptService('SFDialogs.Dialog', None, None, 'myDialog')
         tree = dlg.Controls('myTreeControl')
         root = tree.CreateRoot('Tree top')
         node = tree.AddSubNode(root, 'A branch ...')

## AddSubTree

Return True when a subtree, subordinate to a parent node, could be inserted successfully in a tree control. If the parent node had already child nodes before calling this method, the child nodes are erased.

This method may be called before displaying the dialog box to build the initial tree. It may also be called from a dialog or control event - using the OnNodeExpanded event - to complete the tree dynamically.

### Синтаксис:

svc.AddSubTree(parentnode: uno, flattree: any, opt withdatavalue: bool): bool

### Параметри:

parentnode: A node UNO object, of type com.sun.star.awt.tree.XMutableTreeNode.

flattree: a two dimension array sorted on the columns containing the display values. Such an array can be issued by the GetRows method applied on the SFDatabases.Database service. When an array item containing the text to be displayed is Empty or Null, no new subnode is created and the remainder of the row is skipped.

          Flat tree    >>>>    Resulting subtree
          A1	B1	C1             |__   A1
          A1	B1	C2                   |__   B1
          A1	B2	C3                         |__  C1
          A2	B3	C4                         |__  C2
          A2	B3	C5                   |__   B2
          A3	B4	C6                         |__  C3
                                 |__   A2
                                       |__   B3
                                             |__  C4
                                             |__  C5
                                 |__   A3
                                       |__   B4
                                             |__  C6

withdatavalue: When False default value is used, every column of flattree contains the text to be displayed in the tree control. When True, the texts to be displayed (displayvalue) are in columns 0, 2, 4, ... while the data values (datavalue) are in columns 1, 3, 5, ...

### Пример:

##### В Basic

          Dim myTree As Object, theRoot As Object, oDb As Object, vData As Variant
          Set myTree = myDialog.Controls("myTreeControl")
          Set theRoot = myTree.CreateRoot("By product category")
          Set oDb = CreateScriptService("SFDatabases.Database", "/home/.../mydatabase.odb")
          vData = oDb.GetRows("SELECT [Category].[Name], [Category].[ID], [Product].[Name], [Product].[ID] " _
              & "FROM [Category], [Product] WHERE [Product].[CategoryID] = [Category].[ID] " _
              & "ORDER BY [Category].[Name], [Product].[Name]")
          myTree.AddSubTree(theRoot, vData, WithDataValue := True)

##### В Python

         SQL_STMT = "SELECT [Category].[Name], [Category].[ID], [Product].[Name], [Product].[ID] \
             FROM [Category], [Product] WHERE [Product].[CategoryID] = [Category].[ID] \
             ORDER BY [Category].[Name], [Product].[Name]"
         tree = dlg.Controls('myTreeControl')
         root = tree.CreateRoot('By Product category')
         db = CreateScriptService('SFDatabases.Database', '/home/.../mydatabase.odb')
         sub_tree = db.GetRows(SQL_STMT)
         tree.AddSubTree(root, sub_tree, withdatavalue=True)

## CreateRoot

Returns a new root node of the tree control, as a node UNO object of type com.sun.star.awt.tree.XMutableTreeNode. The new tree root is inserted below pre-existing root nodes. Refer to XMutableTreeNode in Application Programming Interface (API) documentation for detailed information.

This method may be called before displaying the dialog box to build the initial tree. It may also be called from a dialog or control event to complete the tree dynamically.

### Синтаксис:

svc.CreateRoot(displayvalue: str, opt datavalue: any): uno

### Параметри:

displayvalue: The text appearing in the tree control box.

datavalue: Any value associated with the new node. datavalue may be a string, a number or a date. Omit the argument when not applicable.

### Пример:

##### В Basic

          Dim myTree As Object, myNode As Object
          Set myTree = myDialog.Controls("myTreeControl")
          Set myNode = myTree.CreateRoot("Tree starts here ...")

##### В Python

         tree = dlg.Controls('myTreeControl')
         node = tree.CreateRoot('Tree starts here ...')

## FindNode

Traverses the tree and finds recursively, starting from the root, a node meeting some criteria. Either - 1 match is enough - having its display value matching displayvalue pattern or having its data value equal to datavalue. The comparisons may be or not case-sensitive. The first matching occurrence is returned as a node UNO object of type com.sun.star.awt.tree.XMutableTreeNode. Refer to XMutableTreeNode in Application Programming Interface (API) documentation for detailed information.

When not found, the method returns Nothing, to be tested with the IsNull() builtin function.

This method may be called before displaying the dialog box to build the initial tree. It may also be called from a dialog or control event.

### Синтаксис:

svc.FindNode(displayvalue: str = '', opt datavalue: any, casesensitive = False): uno

### Параметри:

One argument out of displayvalue or datavalue must be specified. If both present, one match is sufficient to select the node.

displayvalue: The pattern to be matched. Refer to SF_String.IsLike() method for the list of possible wildcards. When equal to the zero-length string (default), this display value is not searched for.

datavalue: Any value associated with the new node. datavalue may be a string, a number or a date. Omit the argument when not applicable.

casesensitive: Default value is False

### Пример:

##### В Basic

          Dim myTree As Object, myNode As Object
          Set myTree = myDialog.Controls("myTreeControl")
          Set myNode = myTree.FindNode("*Sophie*", CaseSensitive := True)

##### В Python

         tree = dlg.Controls('myTreeControl')
         node = FindNode('*Sophie*', casesensitive=True)
         if node is None:
             # ...

## Resize

Move the top-left corner of a dialog control to new coordinates and/or modify its dimensions. Return True if resizing was successful.

### Синтаксис:

svc.Resize(opt Left: int, opt Top: int, opt Width: int, opt Height: int): bool

### Параметри:

All distances are expressed in Map AppFont units and are measured from the top-left corner of the parent dialog. Without arguments the method resizes the control to its "preferred size", a size adjusted depending on its actual content. Missing arguments are left unchanged.

Left: The horizontal distance from the top-left corner

Top: The vertical distance from the top-left corner

Width: the horizontal width of the rectangle containing the control

Height: the vertical height of the rectangle containing the control

### Пример:

##### В Basic

          Dim oControl As Object
          Set oDlg = CreateScriptService("SFDialogs.Dialog",,, "myDialog")
          Set oControl = oDlg.Controls("thisControl")
          oControl.Resize(100, 200, Height:=6000) ' Width is unchanged

##### В Python

          dlg = CreateScriptService('Dialog', None, None, 'myDialog')
          ctrl = dlg.Controls('thisControl')
          ctrl.Resize(300, 200, 1500)  # Height is unchanged

## SetFocus

Set the focus on the control. Return True if focusing was successful.

This method is often called from a dialog or control event.

### Синтаксис:

svc.SetFocus(): bool

### Пример:

##### В Basic

          Dim oControl As Object
          Set oDlg = CreateScriptService("SFDialogs.Dialog",,, "myDialog")
          Set oControl = oDlg.Controls("thisControl")
          oControl.SetFocus()

##### В Python

          dlg = CreateScriptService('Dialog', None, None, 'myDialog')
          ctrl = dlg.Controls('thisControl')
          ctrl.SetFocus()

## SetTableData

Fills a TableControl with the given data. All preexisting data is cleared before inserting the new data passed as argument.

When the TableControl is added to the dialog, it is possible to use the Basic IDE to define whether column and row headers will be shown in the table. If the TableControl has column and/or row headers, the first column and/or row in the provided data array are used as labels for the table headers.

Този метод връща True при успешно изпълнение.

### Синтаксис:

svc.SetTableData(dataarray: any[0..*, 0..*], widths: int[0..*], alignments: str, RowHeaderWidth = 10): bool

### Параметри:

dataarray: Data to be entered into the table represented as an Array of Arrays in Basic or a tuple of tuples in Python. The data must include column and row headers if they are to be displayed by the TableControl.

widths: Array containing the relative widths of each column. In other words, widths = (1, 2) means that the second column is twice as wide as the first one. If the number of values in the array is smaller than the number of columns in the table, then the last value in the array is used to define the width of the remaining columns.

alignments: Defines the alignment in each column as a string in which each character can be "L" (Left), "C" (Center), "R" (Right) or " " (whitespace, default, meaning left for strings and right for numeric values). If the length of the string is shorter than the number of columns in the table, then the last character in the string is used to define the alignment of the remaining columns.

RowHeaderWidth: width of the row header column expressed in Map AppFont units. Default = 10. The argument is ignored when the TableControl has no row header.

### Пример:

##### В Basic

The following example assumes that the dialog myDialog has a TableControl named Grid1 with "Show row header" and "Show column header" properties set to "Yes".

         Dim myDialog As Object, oTable As Object, tableData As Variant
         myDialog = CreateScriptService("Dialog", "GlobalScope", "Standard", "myDialog")
         oTable = myDialog.Controls("Grid1")
         tableData = Array("Column A", "Column B", "Column C")
         tableData = SF_Array.AppendRow(tableData, Array("Row 1", 1, 2))
         tableData = SF_Array.AppendRow(tableData, Array("Row 2", 3, 4))
         tableData = SF_Array.AppendRow(tableData, Array("Row 3", 5, 6))
         vAlignments = "LCC"
         vWidths = Array(2, 1, 1)
         oTable.SetTableData(tableData, vWidths, vAlignments)
         myDialog.Execute()

The Value property returns the selected row in the table. If no row is selected, an empty Array object is returned. The following code snippet shows how to test if any row is selected in the table.

         rowValues = oTable.Value
         If UBound(rowValues) < 0 Then
             MsgBox "No row selected."
         Else
             MsgBox "Row " & oTable.ListIndex & " is selected."
         End If

##### В Python

         dlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "myDialog")
         table_control = dlg.Controls("Grid1")
         table_data = (("Column A", "Column B", "Column C"),
                       ("Row 1", 1, 2),
                       ("Row 2", 3, 4),
                       ("Row 3", 5, 6))
         alignments = "LCC"
         widths = (100, 50, 50)
         table_control.SetTableData(table_data, widths, alignments)
         dlg.Execute()

         bas = CreateScriptService("Basic")
         row_values = table_control.Value
         if len(row_values) == 0:
             bas.MsgBox("No row selected.")
         else:
             bas.MsgBox(f"Row {table_control.ListIndex} is selected.")

## WriteLine

Add a new line at the end of a multiline text field. A newline character will be inserted when appropriate. The method returns True when successful.

An error is raised if the actual control is not of the type TextField or is not multiline.

### Синтаксис:

svc.WriteLine(opt line: str): bool

### Параметри:

Line: The string to insert. Default is an empty line.

### Пример:

##### В Basic

          Dim oDlg As Object, oControl As Object
          Set oDlg = CreateScriptService("SFDialogs.Dialog",,, "myDialog")
          Set oControl = oDlg.Controls("thisControl")
          oControl.WriteLine("a new line")

##### В Python

         dlg = CreateScriptService('SFDialogs.Dialog', None, None, 'myDialog')
         ctrl = dlg.Controls('thisControl')
         ctr.WriteLine("a new line")

В ScriptForge всички подпрограми или идентификатори на Basic с префикс „_“ са запазени за вътрешна употреба. Те не са предназначени за използване в макроси на Basic.

Теми, свързани с показаната

Услуга SFDialogs.Dialog

ScriptForge.String service

ScriptForge.UI service